Amiga Plus 2002 #3/Amiga Plus CD - 2002 - No. 03.iso/AmigaPlus/Tools/Development/envCPP31/install-vbcc

Text File | 2002-01-01 | 6.3 KB | 313 lines

(complete 0)

(onerror

    (if (> @ioerr 0)

        (
            (message "An error has occurred !")
        )
    )
)

; initialize strings

(if (= @language "deutsch")

    (
        (set #vbcc_missing      "Kann die Installationsdateien von vbcc nicht finden !")

        (set #vbcc_welcome      "Willkommen beim Setup für vbcc !\n\nMit diesem Programm wird die vbcc-Compilerumgebung auf Ihrem Rechner installiert. Versionsstand der Komponenten: vbcc08a")

        (set #vbcc_where        "Wo soll vbcc installiert werden (der Ordner vbcc wird erzeugt) ?")

        (set #vbcc_createerr    "Kann vbcc-Ordner nicht erzeugen !")

        (set #vbcc_startup      "Assigns für vbcc einrichten ?")

        (set #vbcc_required     "vbcc kann ohne die Assigns nicht benutzt werden !")

        (set #vbcc_osincludes   "Wo befinden sich die AmigaOS-Header-Dateien ?")

        (set #vbcc_osndk        "Die AmigaOS-Header sind Bestandteil des NDK (Native Development Toolkit) von Amiga Inc. Sie werden nicht mit vbcc ausgeliefert. Diese Dateien werden für die Entwicklung von Amiga-Anwendungen zwingend benötigt.")
    )

    ; ELSE

    (
        (set #vbcc_missing      "Can not find installation file of vbcc !")

        (set #vbcc_welcome      "Welcome to the setup of vbcc !\n\nThis program installs the vbcc compiler system on your computer. Versions of included components: vbcc08a")

        (set #vbcc_where        "Where do you want to install vbcc (the folder vbcc is created) ?")

        (set #vbcc_createerr    "Can not create vbcc folder !")

        (set #vbcc_startup      "Create assigns for vbcc ?")

        (set #vbcc_required     "vbcc can not be used without these assigns !")

        (set #vbcc_osincludes   "Were are the AmigaOS header files located on your system ?")

        (set #vbcc_osndk        "The AmigaOS headers are part of the NDK (Native Development Toolkit) by Amiga Inc. They are not shipped with vbcc. These files are required for development of AmigaOS software.")
    )
)

; already installed ?

(set #vbcc_include "")

(if (exists "vbcc:" (NOREQ))

    (
        (set @default-dest (pathonly (expandpath "vbcc:")))

        (if (exists "vbcc:include")

            (set #vbcc_include (expandpath "vbcc:include"))
        )
    )

    ; ELSE

    (if (exists "work:" (NOREQ))

        (set @default-dest "work:")

        (set @default-dest "sys:" )
    )
)

(message #vbcc_welcome)

; locate vbcc setup files (located in the bonus folder if this installations runs on a GoldED CD)

(if (exists "targets")

    (set #vbcc_installdata (pathonly (expandpath "")))

    ; ELSE

    (if (exists "////bonus/vbcc/vbcc")

        (set #vbcc_installdata "////bonus/vbcc/vbcc")

        ; ELSE

        (
            (message #vbcc_missing)

            (exit (quiet))
        )
    )
)

; query installation path

(set #vbcc_path

    (askdir

        (prompt #vbcc_where)

        (help @askdir-help)

        (default @default-dest)
    )
)

(set #vbcc_path (tackon #vbcc_path "vbcc"))

(set @default-dest #vbcc_path)

; guess location of os includes

(if (= #vbcc_include "")

    (
        ; golded and ndk installed ?

        (if (exists "golded:" (noreq))

            (if (exists "golded:add-ons/c++/ndk_39/include/include_h")

                (set #vbcc_include (expandpath "golded:add-ons/c++/ndk_39/include/include_h"))
            )
        )

        (if (= #vbcc_include "")

            (
                ; sas/c installed ?

                (if (exists "sc:" (noreq))

                    (if (exists "sc:include")

                        (set #vbcc_include (expandpath "sc:include"))
                    )
                )

                (if (= #vbcc_include "")

                    ; dice installed ?

                    (if (exists "dinclude:" (noreq))

                        (set #vbcc_include (expandpath "dinclude:"))
                    )
                )
            )
        )
    )
)

; query path to os includes

(set #vbcc_include

    (askdir

        (prompt #vbcc_osincludes)

        (help #vbcc_osndk)

        (default #vbcc_include)
    )
)

; create folder for vbcc

(makedir #vbcc_path)

(if (not (exists #vbcc_path))

    (
        (message #vbcc_createerr)

        (exit (quiet))
    )
)

; install vbcc

(copyfiles

    (source #vbcc_installdata)

    (dest #vbcc_path)

    (pattern "~(install#?)")

    (infos)
)

; upgrade vbcc

(if (exists "////bonus/vbcc/vbcc_08a_aos")

    (copyfiles

        (source "////bonus/vbcc/vbcc_08a_aos/vbcc")

        (dest #vbcc_path)

        (all)

        (infos)
    )
)

(makeassign "vbcc" (expandpath #vbcc_path))

; remove write protection for material copied from CD-ROM

(run "programs/unprotect >nil: basedir=vbcc:")

; set script bit for batch files

(if (exists "vbcc:init_vbcc")

    (run "protect vbcc:init_vbcc rweds")
)

(if (exists "vbcc:init_vbcc_new")

    (run "protect vbcc:init_vbcc_new rweds")
)

; update user-startup

(set #vbcc_assigns

    (cat

        ("; amigaos 68k\n")

        ("assign vbcc: \"%s\"\n" (expandpath #vbcc_path))

        ("assign vbccm68k: vbcc:targets/m68k-amigaos defer\n")

        ("assign vincludem68k: vbccm68k:include\n")

        ("assign vincludem68k: \"%s\" add\n" (expandpath #vbcc_include))

        ("assign vlibm68k: vbccm68k:lib defer\n")

        ("; ppc (powerup)\n")

        ("assign vbccppc: vbcc:targets/ppc-powerup defer\n")

        ("assign vincludeppc: vbccppc:include\n")

        ("; assign vincludeppc: <path to your header files> add\n")

        ("assign vlibppc: vbccppc:lib defer\n")

        ("; ppc (warpos)\n")

        ("assign vbccwos: vbcc:targets/ppc-warpos defer\n")

        ("assign vincludewos: vbccwos:include\n")

        ("; assign >NIL: vincludewos: <path to your header files> add\n")

        ("assign vlibwos: vbccwos:lib defer\n")

        ("; morphos\n")

        ("assign vbccmos: vbcc:targets/ppc-morphos defer\n")

        ("assign vincludemos: vbccmos:include\n")

        ("; assign >NIL: vincludemos: <path to your header files> add\n")

        ("assign vlibmos: vbccmos:lib defer\n")

        ("assign c: vbcc:bin add\n")
    )
)

(startup "VBCC"

    (prompt #vbcc_startup)

    (help #vbcc_required)

    (command #vbcc_assigns)
)

; save assigns to temporay batch file and execute it

(textfile (dest "t:vbcc-init") (append  #vbcc_assigns))

(execute "t:vbcc-init")

(delete  "t:vbcc-init")

; done

(exit)

(welcome)